Run Multiple Tasks in the same Command Line using ShellExecuteEx in Delphi

I am trying to run multiple tasks in the same command line using ShellExecuteEx. I have no issue running it in cmd.exe, as shown below:

    C:\Program Files (x86)\AppFolder>App.exe MyTask1&&App.exe MyTask2

    Running task: Task1
    Table: Task1 100
    Complete

    Running task: Task2
    Table: Task2 100
    Complete

    C:\Program Files (x86)\AppFolder>

Now, here's my ShellExecuteEx version in Delphi running one task without any issue:

    procedure TfrmGTX.btnQBSyncClick(Sender: TObject);
     var
       FileName, Parameters, Folder, Directory: string;
       sei: TShellExecuteInfo;
       Error: DWORD;
       OK: boolean;
     begin
       Folder := 'C:\Program Files (x86)\AppFolder\';
       FileName := Folder + 'App.exe';
       Parameters := 'MyTask1';
       ZeroMemory(@sei, SizeOf(sei));
       sei.cbSize := SizeOf(sei);
       sei.lpFile := PChar(FileName);
       sei.lpParameters := PChar(Parameters);
       sei.lpDirectory := PChar(Folder);
       sei.nShow := SW_SHOWNORMAL;
       OK := ShellExecuteEx(@sei);
       if not OK then
         begin
           Error := GetLastError;
           ShowMessage('Error: ' + IntToStr(Error));
         end;
     end;

What I am trying to achieve is to run 2 tasks one after the other using ShellExecuteEx. No pre-condition/relationship between them. Its the same function but serves data to different tables in my database.

My questions are:

  1. Is it possible to run these 2 tasks in 1 ShellExecuteEx command in the parameter? If so, what's the best way to do it inside the parameter?
  2. Or should I create a for loop to run these 2 tasks one after the other?
  3. Or any suggestion?

I prefer the first one as it is cleaner and within the functionalities of ShellExecuteEx.

I have seen some works saying that I should separately run them or create some script.

1 answer

  • answered 2018-01-14 20:00 Alex_89

    I came across this snippet a few years ago when I was trying to get the output of a DOS command. Maybe it'll help you with your problem at hand. You can just call this procedure and any command you pass will be executed. I already tested it passing more than 1 command (joined by an &) and it works perfectly. For example:

    ExecuteDOSCommand('getmac & ipconfig & vol', Output);
    

    It's an alternate way of executing a DOS command. The code is long and somewhat hard to understand, I know, but it may help you too. Just try it out. You shouldn't need to change anything, just call the procedure using your own parameters. Here's the snippet:

    procedure TForm1.ExecuteDOSCommand(Command: String; Output: TStrings; TimeOut: Int64 = 0);
    var
      ProcessStartupInfo: STARTUPINFO;
      SecurityAttributes: SECURITY_ATTRIBUTES;
      SecurityDescriptor: SECURITY_DESCRIPTOR;
      ProcessInformation: PROCESS_INFORMATION;
      PipeReadHandle, PipeWriteHandle: THandle;
      BytesRead, ExitCode: Cardinal;
      Buffer, UnicodeOutput: array[0..4095] of Char;
      NormalizedStr, FullOutputStr: String;
      EndingWaitTime: TDateTime;
    
      function IsWinNT: Boolean;
      var
        OSVerInfo: OSVERSIONINFO;
      begin
        OSVerInfo.dwOSVersionInfoSize := SizeOf(OSVerInfo);
        GetVersionEx(OSVerInfo);
        Result := OSVerInfo.dwPlatformId = VER_PLATFORM_WIN32_NT;
      end;
    
    begin
      Output.Clear;
    
      if IsWinNT then
      begin
        InitializeSecurityDescriptor(@SecurityDescriptor, SECURITY_DESCRIPTOR_REVISION);
        SetSecurityDescriptorDacl(@SecurityDescriptor, True, nil, False);
        SecurityAttributes.lpSecurityDescriptor := @SecurityDescriptor;
      end
      else
        SecurityAttributes.lpSecurityDescriptor := nil;
    
      SecurityAttributes.nLength := SizeOf(SECURITY_ATTRIBUTES);
      SecurityAttributes.bInheritHandle := True;
    
      if CreatePipe(PipeReadHandle, PipeWriteHandle, @SecurityAttributes, 0) then
        try
          GetStartupInfo(ProcessStartupInfo);
    
          with ProcessStartupInfo do
          begin
            dwFlags := STARTF_USESTDHANDLES or STARTF_USESHOWWINDOW;
            wShowWindow := SW_HIDE;
            hStdInput := PipeReadHandle;
            hStdOutput := PipeWriteHandle;
            hStdError := PipeWriteHandle;
          end;
    
          Fillchar(Buffer, SizeOf(Buffer), #0);
          GetEnvironmentVariable('ComSpec', @Buffer, SizeOf(Buffer));
          StrCat(@Buffer, PChar(' /c ' + Command));
    
          if CreateProcess(nil, @Buffer, nil, nil, True, CREATE_NEW_CONSOLE, nil, nil, ProcessStartupInfo, ProcessInformation) then
          begin
            CloseHandle(ProcessInformation.hThread);
            EndingWaitTime := IncMilliSecond(Now, TimeOut);
    
            repeat
              PeekNamedPipe(PipeReadHandle, @Buffer, SizeOf(Buffer), @BytesRead, nil, nil);
    
              if BytesRead > 0 then
              begin
                Fillchar(Buffer, SizeOf(Buffer), #0);
                ReadFile(PipeReadHandle, Buffer, BytesRead, BytesRead, nil);
                FillChar(UnicodeOutput, SizeOf(UnicodeOutput), #0);
                OemToChar(@Buffer, UnicodeOutput);
                NormalizedStr := StringReplace(UnicodeOutput, '♪', #13, [rfReplaceAll]);
                NormalizedStr := StringReplace(NormalizedStr, '◙', #10, [rfReplaceAll]);
                FullOutputStr := FullOutputStr + NormalizedStr;
              end;
    
              GetExitCodeProcess(ProcessInformation.hProcess, ExitCode);
            until ((ExitCode <> STILL_ACTIVE) and (BytesRead = 0)) or ((TimeOut > 0) and (EndingWaitTime < Now));
    
            CloseHandle(ProcessInformation.hProcess);
            Output.Text := FullOutputStr;
          end;
        finally
          CloseHandle(PipeReadHandle);
          CloseHandle(PipeWriteHandle);
        end;
    end;